// New Years 2005 Snowman Card, 31 December 2004
// By Golan Levin, golan at flong dot com
// Revised for Processing Version 125

float R1 = 80;
float R2 = 100;
float R2b = 100;
float R3 = 120;

float Y1, Y2, Y3;
float V1, V2;
float squish = 0.95;
float sx;
float sy;
float spin, mx;

float y_head;
float y_body;
float eye_ratio = 0.280;

float fixed[] = {60, 180, 300};
float eyes[];
float targets[];
float perms[];
int nclicks;
int neyes = 60;
int neyes13 = neyes/3;
int neyes23 = 2*neyes/3;

void setup(){
  size(500, 500, P3D);
  sx = width  * 0.50;
  sy = height * 0.75;
  spin = 0;
  nclicks = 0;

  Y2 = 0;
  Y1 = Y2 - R3;
  Y3 = Y2 + R3*1.2;
  V1 = 0;
  V2 = 0;

  eyes = new float[neyes];
  perms = new float[neyes];
  targets = new float[neyes];
  for (int i=0; i<neyes; i++){
    if (i<(neyes/3)){
      eyes[i] = fixed[0];
    } else if (i>=(2*neyes/3)){
      eyes[i] = fixed[2];
    } else {
      float frac = ((float)(i-neyes13)/(float)(neyes13)) - 0.5;
      eyes[i] = fixed[1] + frac*75;
    }
    targets[i] = eyes[i];
    perms[i] = eyes[i];
  }

}

void mousePressed(){
  nclicks++;

  for (int i=0; i<neyes; i++){
    if (targets[i] == 300){
      eyes[i] -= 360;
    }
  }
  for (int i=0; i<neyes; i++){
    targets[i] = perms[(i + nclicks*neyes13)%neyes];

  }
}

//------------------------------
void mouseDragged(){
  mx = mouseX;
  mx = min(width, max(0, mx));
}
void mouseMoved(){
  mx = mouseX;
  mx = min(width, max(0, mx));
}

//------------------------------
void draw(){
  background(51, 153, 255);

  float F1 = 0.80;
  float F2 = 0.90;
  float K1 = -0.1000;
  float K2 = -0.0833;
  float C = 0.05;
  float ay,vy,py,my,dy;

  my = mouseY - pmouseY;
  my = max(-8, min(8, my));

  float restY2 = 0;
  dy = Y2 - restY2;
  ay = K2*dy + C*my;
  V2 += ay;
  V2 *= F2;
  Y2 += V2;

  float restY1 = Y2 - R3;
  dy = Y1 - restY1;
  ay = K1*dy ;//+ C*my;
  V1 += ay;
  V1 *= F1;
  Y1 += V1;
  
  R2 = R2b + 1.8*sin(millis()/1000.0);
  spin = 0.9*spin + 0.1*(mx-width/2)*0.01;
  mx = 0.97*mx + 0.03*(width/2);

  drawNose();

  for (int i=0; i<neyes; i++){
    eyes[i] = 0.875*eyes[i] + 0.125*targets[i];
    drawEllipseOnSphere(R1, eyes[i], 60);
  }

  drawHat();
  
  drawCircles();
}

//-----------------------------------------

void drawEllipseOnSphere(float r, float theta_deg, float phi_deg){

  float theta = theta_deg * DEG_TO_RAD;
  float phi   = phi_deg   * DEG_TO_RAD;

  phi = HALF_PI - phi;
  fill(0,0,0);
  noStroke();
  ellipseMode(CENTER);

  float x = r * cos(theta) * sin(phi);
  float y = r * sin(theta) * sin(phi);
  float z = r              * cos(phi);
  float e = r * eye_ratio;

  pushMatrix();

  translate(sx, sy + Y1, 0);
  rotateY(spin);

  rotateZ(PI);
  rotateX(0-HALF_PI);
  rotateY(0-HALF_PI);
  rotateX(HALF_PI);
  translate (x, y, z);
  rotateZ(theta);
  rotateY(phi);
  ellipse(0,0, e, e);
  popMatrix();
}


//-----------------------------------------

void drawHat(){

  float px0,py0,pz0;
  float px1,py1,pz1;
  float theta, co,si;
  int nrings = 2;
  int ndivs = 24;
  float hatR = R1*0.60;

  fill(0,0,0); //noFill();
  noStroke();//stroke(0);

  pushMatrix();

  translate(sx, sy + Y1 - R1*squish + R1*0.2, 0);
  scale (hatR, hatR, R1*1.1);
  rotateX(HALF_PI);
  
  beginShape(TRIANGLE_STRIP);
  for (int i=0; i<(ndivs+1); i++){
      theta = (float)i/(float)ndivs * TWO_PI;
      px0  = cos(theta);
      py0  = sin(theta);
      theta = (float)i/(float)ndivs * TWO_PI;
      vertex(px0*1.5,py0*1.5,0);
      vertex(px0,py0,0);
  }
  endShape();

  for (int j=0; j<nrings; j++){
    beginShape(TRIANGLE_STRIP);
    for (int i=0; i<(ndivs+1); i++){
      theta = (float)i/(float)ndivs * TWO_PI;
      co  = cos(theta);
      si  = sin(theta);

      px0 = co;
      py0 = si;
      pz0 = (float)j/(float)(nrings-1);

      px1 = co;
      py1 = si;
      pz1 = (float)(j+1)/(float)(nrings-1);

      vertex(px0, py0, pz0);
      vertex(px1, py1, pz1);

    }
    endShape();
  }
  popMatrix();

}

//--------------------------------------------
void drawNose(){
  fill(255, 192, 0);

  int ndivs = 16;
  int nrings = 4;
  float e = R1 * 0.125;

  pushMatrix();

  translate (sx, sy + Y1, 0);
  rotateY(spin);
  translate (0, 0, R1*0.9);
  scale (e,e, R1*0.9);

  float co, si;
  float r0, r1, theta;
  float px0, py0, pz0;
  float px1, py1, pz1;

  for (int j=0; j<nrings; j++){
    beginShape(TRIANGLE_STRIP);
    for (int i=0; i<(ndivs+1); i++){
      theta = (float)i/(float)ndivs * TWO_PI;
      co  = cos(theta);
      si  = sin(theta);
      r1  = (float)(nrings-j-1)/(float)(nrings-1);
      r0  = (float)(nrings-j  )/(float)(nrings-1);

      px0 = r0 * co;
      py0 = r0 * si;
      pz0 = (float)j/(float)(nrings-1);

      px1 = r1 * co;
      py1 = r1 * si;
      pz1 = (float)(j+1)/(float)(nrings-1);

      vertex(px0, py0, pz0);
      vertex(px1, py1, pz1);

    }
    endShape();
  }
  popMatrix();
}

//------------------------------------
void drawSpheres(){

  fill(255, 255, 255);
  sphereDetail(12);
  noStroke();

  pushMatrix();
  translate(sx, sy, 0);
  rotateY(spin);

  pushMatrix();
  translate (0, Y1, 0);
  scale (1.0, squish, 1.0);
  sphere(R1 * 0.95);
  popMatrix();

  pushMatrix();
  translate (0, Y2, 0);
  scale (1.0, squish, 1.0);
  sphere(R2);
  popMatrix();

  pushMatrix();
  translate (0, Y3, 0);
  scale (1.0, squish, 1.0);
  sphere(R3);
  popMatrix();
  
  popMatrix();

}

//------------------------------------
void drawCircles(){
  fill (255, 255, 255);
  ellipseMode(CENTER);

  pushMatrix();
  translate(sx, sy, 0);

  pushMatrix();
  translate(0, Y1, 0);
  scale (1.0, squish, 1.0);
  ellipse(0, 0, R1*2, R1*2);
  popMatrix();

  pushMatrix();
  translate (0, Y2, 0);
  scale(1.0, squish, 1.0);
  ellipse(0, 0, R2*2, R2*2);
  popMatrix();

  pushMatrix();
  translate (0, Y3, 0);
  scale(1.0, squish, 1.0);
  ellipse(0, 0, R3*2, R3*2);
  popMatrix();

  popMatrix();

}